BBjTabCtrl::insertTab

Description

Insert a tab into the BBjTabCtrl.

Syntax

Return Value

Method

void

insertTab(int index, string title, BBjControl control!)

void

insertTab(int index, string title, int controlID)

void

insertTab(int index, string title, int ImgIndex, BBjControl control!)

void

insertTab(int index, string title, int ImgIndex, int controlID)

Parameters

Variable

Description

index

Specifies 0-based index in which the tab will be inserted.

title

Specifies the tab's title.

control!

Specifies the control that will be displayed in the client area.

ID

Specifies the ID of the control that will be displayed in the client area.

imgIndex

Specifies the index of an image in the image list assigned to the control that will be displayed on the tab. An image list is assigned to the control by calling either the setImageListPath method or the setImageListID method.

Return Value

None.

Remarks

Each tab in the tab control with an index greater or equal to the specified index is shifted upward to have an index one greater than the value it had previously.

When the owner of the parameter does not match the object on which the methods is being called, an !ERROR=208 Multi Thread results. See Accessing Objects From Different Interpreters.

Example

REM Insert tabs into a tab control

REM Obtain the instance of the BBjAPI object
LET myAPI!=BBJAPI()

REM Open the SysGui device
LET SYSGUI=UNT
OPEN (SYSGUI)"X0"

REM Obtain the instance of the BBjSysGui object
LET mySysGui!=myAPI!.getSysGui()

REM Set addWindow param values
LET X=10
LET Y=10
LET WIDTH=400
LET HEIGHT=400
LET TITLE$="BBj Window"

REM Create a window, initialy invisible
LET myWindow!=mySysGui!.addWindow(X,Y,WIDTH,HEIGHT,TITLE$,$00000012$)

REM Add a tab control to the window
LET myTabCtrl!=myWindow!.addTabCtrl(101,50,50,200,200)

REM Create a child window
LET myChildWindow!=myWindow!.addChildWindow(200,75,75,100,100,"",$$,1,$$)

REM Add a static text control on the child window
CHILD_TEXT$="Child Window"
LET myStaticText!=myChildWindow!.addStaticText(300,X,Y,WIDTH,HEIGHT,CHILD_TEXT$)

REM Insert a tab into the tab control using the child window object
myTabCtrl!.insertTab(0,"Tab 4",myChildWindow!)

REM Insert a tab into the tab control using the child window object's ID
myTabCtrl!.insertTab(0,"Tab 3",myChildWindow!.getID())

REM Set an image list for the tab control
myTabCtrl!.setImageListPath("tab.bmp")

REM Insert a tab into the tab control using an image from the image list and the child window object
myTabCtrl!.insertTab(0,"Tab 2",0,myChildWindow!)

REM Insert a tab into the tab control using an image from the image list and the child window object's ID
myTabCtrl!.insertTab(0,"Tab 1",1,myChildWindow!.getID())

REM Set the top level window visible
myWindow!.setVisible(1)

REM Register the CALLBACK routines
CALLBACK(ON_CLOSE,APP_CLOSE,0)

REM Process Events
PROCESS_EVENTS

REM Callback routine called when the user closes the application window
APP_CLOSE:
RELEASE
RETURN

See Also

BBjAPI

BBjSysGui

BBjControl

BBjWindow

BBjMenu

See the BBj Object Diagram for an illustration of the relationship between BBj Objects.



______________________________________________________________________________________

Copyright BASIS International Ltd. BBj®, Visual PRO/5®, PRO/5®, and BBx® are registered trademarks.